/* mousediet.sas */
/* mouse dietary restriction example */
options ls=72 ps=60;
data mice;
   infile 'mousediet.dat';
   input lifetime diet $;
/* fit the cell means model */
proc glm data=mice;
   class diet;
   model lifetime=diet / noint solution clparm ss1 ss2;
/* simple average contrasts */
      estimate 'redaft vs redboth'    diet  0  1 -1 0;
      estimate 'contrd vs restricted' diet  2 -1 -1 0 / divisor=2;
      estimate 'uncontrd vs other'    diet -1 -1 -1 3 / divisor=3;
         contrast 'redaft vs redboth'    diet  0  1 -1 0;
         contrast 'contrd vs restricted' diet  2 -1 -1 0;
         contrast 'uncontrd vs other'    diet -1 -1 -1 3;
      contrast 'among' diet 1 -1 0 0,
                       diet 0 1 -1 0,
                       diet 0 0 1 -1;
/* weighted average contrasts */
      estimate 'redaft vs redboth wt'  diet   0   1  -1   0;
      estimate 'contrd vs restricted wt' diet 127 -71 -56   0 / divisor=127;
      estimate 'uncontrd vs other wt'    diet -57 -71 -56 184 / divisor=184;
         contrast 'redaft vs redboth wt'    diet   0   1  -1   0;
         contrast 'contrd vs restricted wt' diet 127 -71 -56   0;
         contrast 'uncontrd vs other wt'    diet -57 -71 -56 184;
      contrast 'among wt' diet 0 1 -1 0,
                       diet 127 -71 -56   0,
                       diet -57 -71 -56 184;
title 'cell means model';
/* fit the effects model */
proc glm data=mice;
   class diet;
   model lifetime=diet / ss1 ss2;
   means diet;
title 'effects model';
run;